[SI-LIST] Re: si-list Digest V10 #225
- From: Thomas Beneken <thomas.beneken@xxxxxxxxxxx>
- To: si-list@xxxxxxxxxxxxx
- Date: Thu, 19 Aug 2010 11:54:07 +0200
> Msg: #3 in digest
> Date: Tue, 17 Aug 2010 15:19:57 -0400
> From: Scott McMorrow<scott@xxxxxxxxxxxxx>
> Subject: [SI-LIST] Re: TDR in HSPICE from S parameter Touchstone File
>
> As long as you concatenate the s-parameters and remove the duplicate
> point between each sweep segment, you should be fine. If you have
> multiple points at 2.5, 5 and 10 GHz, you do not have a valid Touchstone
> file and your results from tool to tool could be different.
You are right, Scott. Duplicate frequency points are not up to the
touchstone file format spec. Mani sent me his 4 port s-parameters
touchstone file. I peeked into it and it is a perfect valid touchstone
v1.1 file - no duplicate frequency points.
> HSPICE works just fine with S-parameter touchstone files and TDR
> analysis. I personally have experience with 1000's of touchstone files
I converted Mani's 4 port s-parameters to y-(admittance-)parameters by
complex matrix calculations. In a second step I reformatted the
y-parameters into voltage controlled current sources SPICE statements
for each frequency point. The output of an ac analysis with LTspice
resembles the original s-parameter data. The SPICE subcircuit showed to
be correct so far.
* ac Testbench
.PARAM Zo=50
*
X1 P11 P21 P31 P41 0 MyDevice
V1 1 0 AC 1V
R11 1 P11 {Zo}
R21 P21 0 {Zo}
R31 P31 0 {Zo}
R41 P41 0 {Zo}
*
B11 S11 0 V=2*V(P11)-V(1)
B21 S21 0 V=2*V(P21)
B31 S31 0 V=2*V(P31)
B41 S41 0 V=2*V(P41)
*
X2 P12 P22 P32 P42 0 MyDevice
R12 P12 0 {Zo}
V2 2 0 AC 1V
R22 2 P22 {Zo}
R32 P32 0 {Zo}
R42 P42 0 {Zo}
*
B12 S12 0 V=2*V(P12)
B22 S22 0 V=2*V(P22)-V(2)
B32 S32 0 V=2*V(P32)
B42 S42 0 V=2*V(P42)
*
X3 P13 P23 P33 P43 0 MyDevice
R13 P13 0 {Zo}
R23 P23 0 {Zo}
V3 3 0 AC 1V
R33 3 P33 {Zo}
R43 P43 0 {Zo}
*
B13 S13 0 V=2*V(P13)
B23 S23 0 V=2*V(P23)
B33 S33 0 V=2*V(P33)-V(3)
B43 S43 0 V=2*V(P43)
*
X4 P14 P24 P34 P44 0 MyDevice
R14 P14 0 {Zo}
R24 P24 0 {Zo}
R34 P34 0 {Zo}
V4 4 0 AC 1V
R44 4 P44 {Zo}
*
B14 S14 0 V=2*V(P14)
B24 S24 0 V=2*V(P24)
B34 S34 0 V=2*V(P34)
B44 S44 0 V=2*V(P44)-V(4)
*
.AC LIN 400 50MegHz 20GHz
*
.INC "ManiSPICE.cir"
*
.END
>
> in HSPICE. It is your process for creating Touchstone files that
> appears to be broken.
Mani did not get the expected results from tdr simulation with HSPICE.
Using the subcircuit calculated from the s-parameters data he can double
check with any other SPICE simulator.
The outcome might be that the flaw is not in HSPICE but in the original
(measured) data. The DUT is not very well behaved - awful reflections.
Ports 1 is wired to port 2 and port 3 is wired to port 4. Port 1 and 3
are closely coupled whereas port 2 and 4 are not. To be frank, I am not
sure what this DUT is supposed to be. Not one of the biests I am used to.
A step response analysis from input ports 1 and 3 to output ports 2 and
4 with LTspice gives diverging results beyond 1.5 ns. I wounder what
results Mani got with HSPICE. Maybe this is a problem with causality of
input data or maybe this is a limitation of the laplace transformation
algorithm in SPICE. Lots of questions, lots of things to check ...
Maybe Yuriy Shlepnev of Simberian is willing to shed a little light?
Regards
Thomas
>
> regards,
>
> Scott
>
>
> Scott McMorrow
> Teraspeed Consulting Group LLC
> 121 North River Drive
> Narragansett, RI 02882
> (401) 284-1827 Business
> (401) 284-1840 Fax
>
> http://www.teraspeed.com
>
> Teraspeed® is the registered service mark of
> Teraspeed Consulting Group LLC
>
>
> On 8/17/2010 3:11 PM, Mani Ganesan wrote:
>> Hi Thomas
>> first of all thank you for helping me out. I was looking to use HSPICE for
>> all my TDR analysis from my s parameter touchstones. Because in future i
>> will be running lot of simulation and plot TDR. I have only HSPICE tool to
>> do this analysis. I tried in HFSS, but as I am breaking my sweeps in to 4,
>> DC - 2.5GHZ, 2.5-5GHz, 5-10GHz& 10-20GHz, time domain analysis combining
>> the sweeps is not allowed in HFSS.
>>
>> I am not sure how I can create this kind of netlist everytime. I believe
>> HSPICE is not compatible for TDR analysis through s parameter
>> touchstone files.
>>
>> Thank You
>>
>> On Tue, Aug 17, 2010 at 1:00 AM, Thomas Beneken
>> <thomas.beneken@xxxxxxxxxxx>wrote:
>>
>>> Hi Mani,
>>> Am 16.08.2010 20:50, schrieb Mani Ganesan:
>>>
>>> Hi Thomas
>>>
>>> please see the attached touchstone file.
>>>
>>> Your file conformes to touchstone draft spec 1.1 and runs smoothly through
>>> my parser producing a set of complex matrix objects and finally a SPICE
>>> subcircuit.
>>>
>>> The circuit file is attached. si-list does not deliver attachments, so I
>>> give an excerpt to show the general structure:
>>>
>>> *Filename: touchstone\TouchstoneDateien\Meaured_Touchstone.s4p
>>> *Number of ports: 4
>>> *Options: frequency in Hz, scattering parameters given in magnitude-angle
>>> format and normalized to 50.0 ohms
>>> .SUBCKT MyDevice PORT1 PORT2 PORT3 PORT4 GND
>>> R1 PORT1 GND 1E20
>>> R2 PORT2 GND 1E20
>>> R3 PORT3 GND 1E20
>>> R4 PORT4 GND 1E20
>>> G11 PORT1 GND FREQ {V(PORT1,GND)}=
>>> +(50000000.000000,-17.949014,-87.251904)
>>> +...
>>> +(20000000000.000000,-41.008207,-13.381200)
>>> G12 PORT1 GND FREQ {V(PORT2,GND)}=
>>> +(50000000.000000,-17.867432,92.711211)
>>> +...
>>> +(20000000000.000000,-38.455115,72.361854)
>>> G13 PORT1 GND FREQ {V(PORT3,GND)}=
>>> +(50000000.000000,-38.896632,90.725062)
>>> +...
>>> +(20000000000.000000,-49.640741,32.666510)
>>> G14 PORT1 GND FREQ {V(PORT4,GND)}=
>>> +(50000000.000000,-38.772070,-89.365959)
>>> +...
>>> +(20000000000.000000,-50.855923,24.869231)
>>> G21 PORT2 GND FREQ {V(PORT1,GND)}=
>>> +(50000000.000000,-17.867071,92.709127)
>>> +...
>>> +(20000000000.000000,-38.217871,72.339678)
>>> G22 PORT2 GND FREQ {V(PORT2,GND)}=
>>> +(50000000.000000,-17.951140,-87.262368)
>>> +...
>>> +(20000000000.000000,-38.327573,1.253875)
>>> G23 PORT2 GND FREQ {V(PORT3,GND)}=
>>> +(50000000.000000,-38.800696,-89.310398)
>>> +...
>>> +(20000000000.000000,-51.335300,-11.003547)
>>> G24 PORT2 GND FREQ {V(PORT4,GND)}=
>>> +(50000000.000000,-38.839718,90.614642)
>>> +...
>>> +(20000000000.000000,-47.352710,-56.426149)
>>> G31 PORT3 GND FREQ {V(PORT1,GND)}=
>>> +(50000000.000000,-38.882783,90.699194)
>>> +...
>>> +(20000000000.000000,-50.087806,30.341649)
>>> G32 PORT3 GND FREQ {V(PORT2,GND)}=
>>> +(50000000.000000,-38.787225,-89.331855)
>>> +...
>>> +(20000000000.000000,-51.956991,-12.316113)
>>> G33 PORT3 GND FREQ {V(PORT3,GND)}=
>>> +(50000000.000000,-18.022983,-89.691485)
>>> +...
>>> +(20000000000.000000,-41.759080,7.093813)
>>> G34 PORT3 GND FREQ {V(PORT4,GND)}=
>>> +(50000000.000000,-17.913241,90.257573)
>>> +...
>>> +(20000000000.000000,-39.793985,46.202557)
>>> G41 PORT4 GND FREQ {V(PORT1,GND)}=
>>> +(50000000.000000,-38.758925,-89.379610)
>>> +...
>>> +(20000000000.000000,-50.811204,27.077517)
>>> G42 PORT4 GND FREQ {V(PORT2,GND)}=
>>> +(50000000.000000,-38.826879,90.604107)
>>> +...
>>> +(20000000000.000000,-47.585828,-53.927695)
>>> G43 PORT4 GND FREQ {V(PORT3,GND)}=
>>> +(50000000.000000,-17.913878,90.248990)
>>> +...
>>> +(20000000000.000000,-39.232342,49.802173)
>>> G44 PORT4 GND FREQ {V(PORT4,GND)}=
>>> +(50000000.000000,-17.964787,-89.788141)
>>> +...
>>> +(20000000000.000000,-36.899614,9.530516)
>>> .ENDS
>>>
>>>
>>> Thank You for your help.
>>> Mani
>>>
>>> On Mon, Aug 16, 2010 at 3:11 AM, Thomas Beneken<
>>> thomas.beneken@xxxxxxxxxxx> wrote:
>>>
>>>>> -----Original Message-----
>>>>> From: si-list-bounce@xxxxxxxxxxxxx [mailto:si-list-bounce@xxxxxxxxxxxxx]
>>>> On
>>>>> Behalf Of Mani Ganesan
>>>>>
>>>>> Sent: Thursday, August 05, 2010 07:04 PM
>>>>> To: si-list@xxxxxxxxxxxxx
>>>>> Subject: [SI-LIST] TDR in HSPICE from S parameter Touchstone File
>>>>>
>>>>> Hi All
>>>>> I have a small problem in doing TDR in HSPICE. I simulated my high speed
>>>>> trace in HFSS and got the s parameter touchstone file from DC to 20GHz
>>>>> incrementing at 10MHz.
>>>>>
>>>>> I am trying to do TDR anlysis in HSPICE and would like to plot it.
>>>>>
>>>>> Can anyone confirm my following netlist and please let me know my
>>>> mistakes
>>>>> as the impdeance TDR output is not correct? Please see the attached TDR
>>>>> output.
>>>> If you mistrust HSPICE in working on your touchstone file correctly, I
>>>> can offer you to calculate a 4-port SPICE subcircuit consisting of a
>>>> mesh of frequency dependent / voltage controlled current sources for
>>>> you. You can verify the s-parameters by ac analysis before doing tdr
>>>> analysis. Works with any flavour of SPICE.
>>>> Please send me your touchstone file by private email because si-list
>>>> does not allow attachments.
>>>>
>>>> Regards
>>>> Thomas
>>>>
------------------------------------------------------------------
To unsubscribe from si-list:
si-list-request@xxxxxxxxxxxxx with 'unsubscribe' in the Subject field
or to administer your membership from a web page, go to:
//www.freelists.org/webpage/si-list
For help:
si-list-request@xxxxxxxxxxxxx with 'help' in the Subject field
List technical documents are available at:
http://www.si-list.net
List archives are viewable at:
//www.freelists.org/archives/si-list
Old (prior to June 6, 2001) list archives are viewable at:
http://www.qsl.net/wb6tpu
Other related posts:
- » [SI-LIST] Re: si-list Digest V10 #225 - Thomas Beneken
