[SI-LIST] Re: Loss in HSPICE W Element
- From: Alain Everaert <everaeal@xxxxxxxxxxxxxxxxx>
- To: Timothy.Coyle@xxxxxxx
- Date: Fri, 14 Mar 2003 15:20:44 +0100
Hi Timothy,
you've defined a copper material but you did not use it for the definition of
your conductors. You should modify your diff_microstrip description to :
.MODEL diff_microstrip W MODELTYPE=FieldSolver,
+ LAYERSTACK=diff_micro, FSOPTIONS=opt1,
+ RLGCFILE=diffmicro.rlgc
+ CONDUCTOR=(SHAPE=rect, ORIGIN=(0,3.5mil), MATERIAL = COPPER),
+ CONDUCTOR=(SHAPE=rect, ORIGIN=(100mil,3.5mil), MATERIAL = COPPER)
Doing so, I got following results :
*SYSTEM_NAME : diff_microstrip
*
* Half Space, air
* ------------------------------------ Z = 8.99e-05
* fr4 H = 8.89e-05
* ------------------------------------ Z = 1e-06
* //// Bottom Ground Plane ///////////
* ------------------------------------ Z = 0
* L(H/m), C(F/m), Ro(Ohm/m), Go(S/m), Rs(Ohm/(m*sqrt(Hz)), Gd(S/(m*Hz))
.MODEL diff_microstrip W MODELTYPE=RLGC, N=2
+ Lo = 2.88615e-07
+ 6.05346e-10 2.88615e-07
+ Co = 1.10532e-10
+ -4.75545e-14 1.10532e-10
+ Ro = 3.69891e+00
+ 0.00000e+00 3.69891e+00
+ Go = 0.00000e+00
+ -0.00000e+00 0.00000e+00
+ Rs = 8.68677e-04
+ 2.12306e-06 8.68677e-04
+ Gd = 6.25043e-12
+ -2.68914e-15 6.25043e-12
I've used HSpice, version 2001.4.2
Regards,
Alain.
Timothy Coyle wrote:
> Hi,
> I have made a 100 Ohm differential microstrip trace using the HSPICE field
> solver. I am trying to get the field solver to give
> loss results, such as Rs and Ro. But each time I run HSPICE, I only get L
> and C values. Can anyone see what I might be
> doing wrong? I am using version 2001.2
>
> Thanks,
> Tim
>
> *
> * Define the board materials
> .MATERIAL dielectric_fr4 DIELECTRIC ER=4.2 LOSSTANGENT=0.02
> .MATERIAL copper METAL Conductivity=5.813E7
>
> * Define the cross section of the traces as a rectangle
> * 1.0 oz. copper has height of 1.44mils
> .SHAPE rect RECTANGLE WIDTH=6mil, HEIGHT=1.2mil
>
> * Define the layer stackup
> * Layer=(material name, thickness)
> .LAYERSTACK diff_micro
> + LAYER=(PEC,1um) * ideal air (top layer)
> + LAYER=(dielectric_fr4,3.5mil) * dielectric layer
>
> * Define Field Solver Options
> .FSOPTIONS opt1 PRINTDATA=yes
> + ACCURACY=HIGH
> + ComputeRo=yes ComputeRs=yes ComputeGo=Yes ComputeGd=yes
> * Model Definition
> .MODEL diff_microstrip W MODELTYPE=FieldSolver,
> + LAYERSTACK=diff_micro, FSOPTIONS=opt1,
> + RLGCFILE=diffmicro.rlgc
> + CONDUCTOR=(SHAPE=rect, ORIGIN=(0,3.5mil)),
> + CONDUCTOR=(SHAPE=rect, ORIGIN=(100mil,3.5mil))
> *
>
> *SYSTEM_NAME : diff_microstrip
> *
> * Half Space, air
> * ------------------------------------ Z = 8.99e-05
> * dielectric_fr4 H = 8.89e-05
> * ------------------------------------ Z = 1e-06
> * //// Bottom Ground Plane ///////////
> * ------------------------------------ Z = 0
>
> * L(H/m), C(F/m), Ro(Ohm/m), Go(S/m), Rs(Ohm/(m*sqrt(Hz)), Gd(S/(m*Hz))
>
> .MODEL diff_microstrip W MODELTYPE=RLGC, N=2
> + Lo = 2.88615e-07
> + 6.05346e-10 2.88615e-07
> + Co = 1.15222e-10
> + -4.70212e-14 1.15222e-10
> + Ro = 0.00000e+00
> + 0.00000e+00 0.00000e+00
> + Go = 0.00000e+00
> + -0.00000e+00 0.00000e+00
> + Rs = 0.00000e+00
> + 0.00000e+00 0.00000e+00
>
> ------------------------------------------------------------------
> To unsubscribe from si-list:
> si-list-request@xxxxxxxxxxxxx with 'unsubscribe' in the Subject field
>
> or to administer your membership from a web page, go to:
> //www.freelists.org/webpage/si-list
>
> For help:
> si-list-request@xxxxxxxxxxxxx with 'help' in the Subject field
>
> List archives are viewable at:
> //www.freelists.org/archives/si-list
> or at our remote archives:
> http://groups.yahoo.com/group/si-list/messages
> Old (prior to June 6, 2001) list archives are viewable at:
> http://www.qsl.net/wb6tpu
>
------------------------------------------------------------------
To unsubscribe from si-list:
si-list-request@xxxxxxxxxxxxx with 'unsubscribe' in the Subject field
or to administer your membership from a web page, go to:
//www.freelists.org/webpage/si-list
For help:
si-list-request@xxxxxxxxxxxxx with 'help' in the Subject field
List archives are viewable at:
//www.freelists.org/archives/si-list
or at our remote archives:
http://groups.yahoo.com/group/si-list/messages
Old (prior to June 6, 2001) list archives are viewable at:
http://www.qsl.net/wb6tpu
Other related posts:
