[SI-LIST] Re: Hspice B element
- From: Adam.Tambone@xxxxxxxxxxxxxxxxx
- To: Andrew.Ingraham@xxxxxxxxxx
- Date: Fri, 25 Jan 2002 09:09:27 -0500
Shown below is a netlist utilizing the B-Element as a I/O buffer in HSPICE.
Note the keyword 'Ramp' specific to the B-Element. Ramp = 0 will take edge
rate information from the Ramp data in the IBIS datasheet, Ramp = 1 will
use the first Rising and Falling Waveforms in the IBIS datasheet, and Ramp
= 2 will utilize two Rising and Falling Waveforms for edge rate and shape
information.
Rgds,
Adam Tambone
**********************************************************
*
*
* lvx3245 5V Vcc B pin I/O
*
*
* by Adam Tambone
*
* August, 2001
**********************************************************
.option post probe
+ d_ibis='/home/atambone/aa_ibis_testing/lvx_test_environments/'
**********************************************************
* Analysis and Stimuli
**********************************************************
* 20MHz
V_in20 nd_in 0 3.3V pulse ( 0V 3.3V 1n 2n 2n 23n 50n )
.tran 0.02n 51n
* 33MHz
*V_in33 nd_in 0 3.3V pulse ( 0V 3.3V 1n 2n 2n 13.15n 30.303n )
*.tran 0.02n 32n
* 66MHz
*V_in66 nd_in 0 3.3V pulse ( 0V 3.3V 1n 2n 2n 5.7575n 15.515n )
*.tran 0.02n 17n
* 100MHz
*V_in100 nd_in 0 3.3V pulse ( 0V 3.3V 1n 2n 2n 3n 10n )
*.tran 0.02n 11n
**********************************************************
* LOAD
**********************************************************
* vinr needed for i/o buffer acting as input buffer
VINR nd_in2 0 DC 0
Vend nd_en 0 dc 0
Venr nd_en2 0 dc 0
**********************************************************
* Output
**********************************************************
.plot tran
* driver
+ v(nd_out) v(nd_in)
* receiver
+ v(nd_out2)
*+ i1(rt) i2(rt)
**********************************************************
* DRIVER OUTPUT BUFFERS
**********************************************************
b_io nd_pu nd_pd nd_out nd_in nd_en v_out_of_in [nd_pc nd_gc]
+ file = 'lvx3245mtc.ibs'
+ model = 'data_io_b'
+ ramp_rwf = 2
+ ramp_fwf = 2
*+ fwf_tune = 1.0
**********************************************************
* RECEIVER INPUT BUFFERS
**********************************************************
b_rcvr nd_pu2 nd_pd2 nd_out2 nd_in2 nd_en2 v_out_of_in2 [nd_pc2 nd_gc2]
+ file = 'lvx3245mtc.ibs'
+ model = 'data_io_b'
+ ramp_rwf = 2
+ ramp_fwf = 2
**********************************************************
* TRANSMISSION LINE
**********************************************************
T1 nd_out 0 nd_out2 0 Z0=50 TD=1.0n L=0.3048
* different lengths
*L=0.1524
*L=0.3048
*L=0.6096
.end
"Ingraham, Andrew" <Andrew.Ingraham@xxxxxxxxxx>@freelists.org on 01/25/2002
08:18:04 AM
Please respond to Andrew.Ingraham@xxxxxxxxxx
Sent by: si-list-bounce@xxxxxxxxxxxxx
To: <si-list@xxxxxxxxxxxxx>
cc:
Subject: [SI-LIST] Re: Hspice B element
> ---------------
> *
> *
> *
> -----------------
> for the hspice output and
>=20
> --------------
> *
> *
> *
> ------------------------
> for the IBIS output.
>=20
> What could I be doing wrong here? Any inputs will be appreciated.
>=20
>=20
Some things to check:
Is the B-element connected correctly? Are you using the right B-element
node for connection to the rest of your circuit?
What is the load?
Double-check the units in the IBIS datasheet file ("model").
Is the risetime the only difference, or are the initial and final
voltage levels wrong too?
Regards,
Andy
------------------------------------------------------------------
To unsubscribe from si-list:
si-list-request@xxxxxxxxxxxxx with 'unsubscribe' in the Subject field
or to administer your membership from a web page, go to:
//www.freelists.org/webpage/si-list
For help:
si-list-request@xxxxxxxxxxxxx with 'help' in the Subject field
List archives are viewable at:
//www.freelists.org/archives/si-list
or at our remote archives:
http://groups.yahoo.com/group/si-list/messages
Old (prior to June 6, 2001) list archives are viewable at:
http://www.qsl.net/wb6tpu
------------------------------------------------------------------
To unsubscribe from si-list:
si-list-request@xxxxxxxxxxxxx with 'unsubscribe' in the Subject field
or to administer your membership from a web page, go to:
//www.freelists.org/webpage/si-list
For help:
si-list-request@xxxxxxxxxxxxx with 'help' in the Subject field
List archives are viewable at:
//www.freelists.org/archives/si-list
or at our remote archives:
http://groups.yahoo.com/group/si-list/messages
Old (prior to June 6, 2001) list archives are viewable at:
http://www.qsl.net/wb6tpu
Other related posts:
