[SI-LIST] Re: Hspice Fieldsolver Question

> I got an error "Singular MOM Matrix" when running Hspice fieldsolver,
> the source code is at below.
> I found that if I change trace width(W_MB) from 6 to 4 mils, it would
> work.
> Looking for inputs on causes for this error and work around.
> Thanks a lot,
>Bowen
>

Dear Bowen and others,

First, I like to wish everyone a very happy Thanksgiving!!

In regard to the source code, after removing some "3D" and
extra " = " characters, I was able to execute it (using HSPICE 2001.4.2 ).
 My conclusions (please correct me if I am mistaken) are listed below:

1. The geometry involves three microstrip traces
of rectangular cross section; the aim being to determine their coupling.

2. The lower left corner coordinates of
each rectangle, as given by the " origin " in .MODEL statement are:

Origin=(0,'0.0254e-3*(T_PLANE+H_MB)' )
Origin=('0.0254e-3*MB_U_GRID','0.0254e-3*(T_PLANE+H_MB)')
Origin=3D('2*0.0254e-3*MB_U_GRID','0.0254e-3*(T_PLANE+H_MB))

3. The three traces are at equal height from the ground plane since the
"origin"
statements have same " Y " coordinate e.g.  0.0254e-3*(T_PLANE+H_MB).

4. The origins' " X " coordinates (which depend on parameter MB_U_GRID) and
the
thickness of each trace ( given by parameter W_MB ) define the separation
of the lines.

5. It is expected to see ERROR when traces overlap.
This happens when " MB_U_GRID -  W_MB  "  is non-positive.

6. There is also ERROR when trace width is less than 4.1, even if the
edge-to-edge separation of neighboring traces (e.g.  " MB_U_GRID -  W_MB " )
is positive


I have attached the edited (e.g. special characters removed) netlist hoping
the HSPICE experts can explain the source of ERROR when trace width
exceeds 4.1 mils.


**********************************************************
**********************************************************
.tran 0.01n 20n
V1 1 0 10 AC 1 PULSE 0 5 10N 20N 20N 500N 2U
R1 1 2 1K
R2 2 0 1K
C1 2 0 .001U


.option post=1
.option probe

.param MB_U_GRID= 10
.param Er_MB=5
.param Er_MB_SM=3
.param H_MB=2
.param W_MB= 4.1     $-originally 6
.param T_MB=1
.param T_Er_MB=0.25
.param T_PLANE=1.2

**********
*Materials
**********
.material diel_MB Dielectric ER=Er_MB Losstangent=0.027
.material diel_MB_SM Dielectric ER=Er_MB_SM Losstangent=0.027
.material trace METAL CONDUCTIVITY=31meg
.material gnd_plane METAL CONDUCTIVITY=31meg

**********
*SHAPE
**********
.shape rect_TL0 Rectangle Width='W_MB*0.0254e-3' Height='T_MB*0.0254e-3'

***********
*STACKUP
***********
.Layerstack  stack_TL0
+Layer=(gnd_plane,'0.0254e-3*T_PLANE')
+Layer=(diel_MB,'0.0254e-3*H_MB')
+Layer=(diel_MB_SM,'0.0254e-3*T_Er_MB')

******************
*option settings
******************
.fsoptions opt1 accuracy=high printdata=yes
+COMPUTEGD=YES, COMPUTERS=YES

*****************
*conductors
*****************
.MODEL U_MB W Modeltype=FieldSolver,
+LayerStack= stack_TL0, Fsoptions=opt1,
+RLGCFILE=test.rlc
+conductor=(shape=rect_TL0, MATERIAL=TRACE,
+TYPE=SIGNAL,Origin=(0,'0.0254e-3*(T_PLANE+H_MB)')),
+conductor=(shape=rect_TL0,MATERIAL=TRACE,
+TYPE=SIGNAL,Origin=('0.0254e-3*MB_U_GRID','0.0254e-3*(T_PLANE+H_MB)')),
+conductor=(shape=rect_TL0,MATERIAL=TRACE,
+TYPE=SIGNAL,Origin=('2*0.0254e-3*MB_U_GRID','0.0254e-3*(T_PLANE+H_MB)'))

.end

********************************************************************
********************************************************************

Kind Regards,

Abe Riazi
ServerWorks













------------------------------------------------------------------
To unsubscribe from si-list:
si-list-request@xxxxxxxxxxxxx with 'unsubscribe' in the Subject field

or to administer your membership from a web page, go to:
http://www.freelists.org/webpage/si-list

For help:
si-list-request@xxxxxxxxxxxxx with 'help' in the Subject field

List technical documents are available at:
                http://www.si-list.org

List archives are viewable at:     
                http://www.freelists.org/archives/si-list
or at our remote archives:
                http://groups.yahoo.com/group/si-list/messages 
Old (prior to June 6, 2001) list archives are viewable at:
                http://www.qsl.net/wb6tpu

Other related posts: