[linux-cirrus] Re: Problems with edb9302a on kernel-2.6.20-rc7
- From: NZG <ngustavson@xxxxxxxxxxx>
- To: linux-cirrus@xxxxxxxxxxxxx
- Date: Fri, 2 Feb 2007 17:06:48 -0600
Patch fails to apply to 2.6.20-rc7.
A conflict? Doen't look like it to me, but you may want to have a peek.
rej, orig, and theoretical new patch follow.
Building it right now.
It looks like the RUNTIME_PHYS_OFFSET is selected automatically and silently
for ep93xx builds, is this the desired behavior? Am I looking at this wrong?
P.S, what diff options did you use to make the original?
Looks prettier than mine.
patching file arch/arm/Kconfig
patching file arch/arm/boot/compressed/Makefile
patching file arch/arm/boot/compressed/head.S
patching file arch/arm/kernel/head.S
Hunk #1 succeeded at 43 (offset 4 lines).
Hunk #2 succeeded at 206 (offset 4 lines).
Hunk #3 FAILED at 267.
1 out of 3 hunks FAILED -- saving rejects to file arch/arm/kernel/head.S.rej
patching file arch/arm/kernel/setup.c
patching file arch/arm/mach-ep93xx/Makefile.boot
patching file include/asm-arm/arch-ep93xx/memory.h
patching file include/asm-arm/memory.h
On Friday 02 February 2007 4:15 pm, Lennert Buytenhek wrote:
> As a guess, can you try:
>
> http://svn.wantstofly.org/kernel/dynamic-phys-offset.diff
/*
* linux/arch/arm/kernel/head.S
*
* Copyright (C) 1994-2002 Russell King
* Copyright (c) 2003 ARM Limited
* All Rights Reserved
*
* This program is free software; you can redistribute it and/or modify
* it under the terms of the GNU General Public License version 2 as
* published by the Free Software Foundation.
*
* Kernel startup code for all 32-bit CPUs
*/
#include <linux/linkage.h>
#include <linux/init.h>
#include <asm/assembler.h>
#include <asm/domain.h>
#include <asm/ptrace.h>
#include <asm/asm-offsets.h>
#include <asm/memory.h>
#include <asm/thread_info.h>
#include <asm/system.h>
#if (PHYS_OFFSET & 0x001fffff)
#error "PHYS_OFFSET must be at an even 2MiB boundary!"
#endif
#define KERNEL_RAM_VADDR (PAGE_OFFSET + TEXT_OFFSET)
#define KERNEL_RAM_PADDR (PHYS_OFFSET + TEXT_OFFSET)
/*
* swapper_pg_dir is the virtual address of the initial page table.
* We place the page tables 16K below KERNEL_RAM_VADDR. Therefore, we must
* make sure that KERNEL_RAM_VADDR is correctly set. Currently, we expect
* the least significant 16 bits to be 0x8000, but we could probably
* relax this restriction to KERNEL_RAM_VADDR >= PAGE_OFFSET + 0x4000.
*/
#if (KERNEL_RAM_VADDR & 0xffff) != 0x8000
#error KERNEL_RAM_VADDR must start at 0xXXXX8000
#endif
.globl swapper_pg_dir
.equ swapper_pg_dir, KERNEL_RAM_VADDR - 0x4000
.macro pgtbl, rd
ldr \rd, =(KERNEL_RAM_PADDR - 0x4000)
.endm
#ifdef CONFIG_XIP_KERNEL
#define TEXTADDR XIP_VIRT_ADDR(CONFIG_XIP_PHYS_ADDR)
#else
#define TEXTADDR KERNEL_RAM_VADDR
#endif
/*
* Kernel startup entry point.
* ---------------------------
*
* This is normally called from the decompressor code. The requirements
* are: MMU = off, D-cache = off, I-cache = dont care, r0 = 0,
* r1 = machine nr.
*
* This code is mostly position independent, so if you link the kernel at
* 0xc0008000, you call this at __pa(0xc0008000).
*
* See linux/arch/arm/tools/mach-types for the complete list of machine
* numbers for r1.
*
* We're trying to keep crap to a minimum; DO NOT add any machine specific
* crap here - that's what the boot loader (or in extreme, well justified
* circumstances, zImage) is for.
*/
__INIT
.type stext, %function
ENTRY(stext)
msr cpsr_c, #PSR_F_BIT | PSR_I_BIT | SVC_MODE @ ensure svc mode
@ and irqs disabled
mrc p15, 0, r9, c0, c0 @ get processor id
bl __lookup_processor_type @ r5=procinfo r9=cpuid
movs r10, r5 @ invalid processor (r5=0)?
beq __error_p @ yes, error 'p'
bl __lookup_machine_type @ r5=machinfo
movs r8, r5 @ invalid machine (r5=0)?
beq __error_a @ yes, error 'a'
bl __create_page_tables
/*
* The following calls CPU specific code in a position independent
* manner. See arch/arm/mm/proc-*.S for details. r10 = base of
* xxx_proc_info structure selected by __lookup_machine_type
* above. On return, the CPU will be ready for the MMU to be
* turned on, and r0 will hold the CPU control register value.
*/
ldr r13, __switch_data @ address to jump to after
@ mmu has been enabled
adr lr, __enable_mmu @ return (PIC) address
add pc, r10, #PROCINFO_INITFUNC
#if defined(CONFIG_SMP)
.type secondary_startup, #function
ENTRY(secondary_startup)
/*
* Common entry point for secondary CPUs.
*
* Ensure that we're in SVC mode, and IRQs are disabled. Lookup
* the processor type - there is no need to check the machine type
* as it has already been validated by the primary processor.
*/
msr cpsr_c, #PSR_F_BIT | PSR_I_BIT | SVC_MODE
mrc p15, 0, r9, c0, c0 @ get processor id
bl __lookup_processor_type
movs r10, r5 @ invalid processor?
moveq r0, #'p' @ yes, error 'p'
beq __error
/*
* Use the page tables supplied from __cpu_up.
*/
adr r4, __secondary_data
ldmia r4, {r5, r7, r13} @ address to jump to after
sub r4, r4, r5 @ mmu has been enabled
ldr r4, [r7, r4] @ get secondary_data.pgdir
adr lr, __enable_mmu @ return address
add pc, r10, #PROCINFO_INITFUNC @ initialise processor
@ (return control reg)
/*
* r6 = &secondary_data
*/
ENTRY(__secondary_switched)
ldr sp, [r7, #4] @ get secondary_data.stack
mov fp, #0
b secondary_start_kernel
.type __secondary_data, %object
__secondary_data:
.long .
.long secondary_data
.long __secondary_switched
#endif /* defined(CONFIG_SMP) */
/*
* Setup common bits before finally enabling the MMU. Essentially
* this is just loading the page table pointer and domain access
* registers.
*/
.type __enable_mmu, %function
__enable_mmu:
#ifdef CONFIG_ALIGNMENT_TRAP
orr r0, r0, #CR_A
#else
bic r0, r0, #CR_A
#endif
#ifdef CONFIG_CPU_DCACHE_DISABLE
bic r0, r0, #CR_C
#endif
#ifdef CONFIG_CPU_BPREDICT_DISABLE
bic r0, r0, #CR_Z
#endif
#ifdef CONFIG_CPU_ICACHE_DISABLE
bic r0, r0, #CR_I
#endif
mov r5, #(domain_val(DOMAIN_USER, DOMAIN_MANAGER) | \
domain_val(DOMAIN_KERNEL, DOMAIN_MANAGER) | \
domain_val(DOMAIN_TABLE, DOMAIN_MANAGER) | \
domain_val(DOMAIN_IO, DOMAIN_CLIENT))
mcr p15, 0, r5, c3, c0, 0 @ load domain access register
mcr p15, 0, r4, c2, c0, 0 @ load page table pointer
b __turn_mmu_on
/*
* Enable the MMU. This completely changes the structure of the visible
* memory space. You will not be able to trace execution through this.
* If you have an enquiry about this, *please* check the linux-arm-kernel
* mailing list archives BEFORE sending another post to the list.
*
* r0 = cp#15 control register
* r13 = *virtual* address to jump to upon completion
*
* other registers depend on the function called upon completion
*/
.align 5
.type __turn_mmu_on, %function
__turn_mmu_on:
mov r0, r0
mcr p15, 0, r0, c1, c0, 0 @ write control reg
mrc p15, 0, r3, c0, c0, 0 @ read id reg
mov r3, r3
mov r3, r3
mov pc, r13
/*
* Setup the initial page tables. We only setup the barest
* amount which are required to get the kernel running, which
* generally means mapping in the kernel code.
*
* r8 = machinfo
* r9 = cpuid
* r10 = procinfo
*
* Returns:
* r0, r3, r6, r7 corrupted
* r4 = physical page table address
*/
.type __create_page_tables, %function
__create_page_tables:
pgtbl r4 @ page table address
/*
* Clear the 16K level 1 swapper page table
*/
mov r0, r4
mov r3, #0
add r6, r0, #0x4000
1: str r3, [r0], #4
str r3, [r0], #4
str r3, [r0], #4
str r3, [r0], #4
teq r0, r6
bne 1b
ldr r7, [r10, #PROCINFO_MM_MMUFLAGS] @ mm_mmuflags
/*
* Create identity mapping for first MB of kernel to
* cater for the MMU enable. This identity mapping
* will be removed by paging_init(). We use our current program
* counter to determine corresponding section base address.
*/
mov r6, pc, lsr #20 @ start of kernel section
orr r3, r7, r6, lsl #20 @ flags + kernel base
str r3, [r4, r6, lsl #2] @ identity mapping
/*
* Now setup the pagetables for our kernel direct
* mapped region.
*/
add r0, r4, #(TEXTADDR & 0xff000000) >> 18 @ start of kernel
str r3, [r0, #(TEXTADDR & 0x00f00000) >> 18]!
ldr r6, =(_end - PAGE_OFFSET - 1) @ r6 = number of sections
mov r6, r6, lsr #20 @ needed for kernel minus 1
1: add r3, r3, #1 << 20
str r3, [r0, #4]!
subs r6, r6, #1
bgt 1b
/*
* Then map first 1MB of ram in case it contains our boot params.
*/
add r0, r4, #PAGE_OFFSET >> 18
orr r6, r7, #(PHYS_OFFSET & 0xff000000)
orr r6, r6, #(PHYS_OFFSET & 0x00e00000)
str r6, [r0]
#ifdef CONFIG_XIP_KERNEL
/*
* Map some ram to cover our .data and .bss areas.
* Mapping 3MB should be plenty.
*/
sub r3, r4, #PHYS_OFFSET
mov r3, r3, lsr #20
add r0, r0, r3, lsl #2
add r6, r6, r3, lsl #20
str r6, [r0], #4
add r6, r6, #(1 << 20)
str r6, [r0], #4
add r6, r6, #(1 << 20)
str r6, [r0]
#endif
#ifdef CONFIG_DEBUG_LL
ldr r7, [r10, #PROCINFO_IO_MMUFLAGS] @ io_mmuflags
/*
* Map in IO space for serial debugging.
* This allows debug messages to be output
* via a serial console before paging_init.
*/
ldr r3, [r8, #MACHINFO_PGOFFIO]
add r0, r4, r3
rsb r3, r3, #0x4000 @ PTRS_PER_PGD*sizeof(long)
cmp r3, #0x0800 @ limit to 512MB
movhi r3, #0x0800
add r6, r0, r3
ldr r3, [r8, #MACHINFO_PHYSIO]
orr r3, r3, r7
1: str r3, [r0], #4
add r3, r3, #1 << 20
teq r0, r6
bne 1b
#if defined(CONFIG_ARCH_NETWINDER) || defined(CONFIG_ARCH_CATS)
/*
* If we're using the NetWinder or CATS, we also need to map
* in the 16550-type serial port for the debug messages
*/
add r0, r4, #0xff000000 >> 18
orr r3, r7, #0x7c000000
str r3, [r0]
#endif
#ifdef CONFIG_ARCH_RPC
/*
* Map in screen at 0x02000000 & SCREEN2_BASE
* Similar reasons here - for debug. This is
* only for Acorn RiscPC architectures.
*/
add r0, r4, #0x02000000 >> 18
orr r3, r7, #0x02000000
str r3, [r0]
add r0, r4, #0xd8000000 >> 18
str r3, [r0]
#endif
#endif
mov pc, lr
.ltorg
#include "head-common.S"
*************** __create_page_tables:
*** 255,261 ****
* Then map first 1MB of ram in case it contains our boot params.
*/
add r0, r4, #PAGE_OFFSET >> 18
- orr r6, r7, #PHYS_OFFSET
str r6, [r0]
#ifdef CONFIG_XIP_KERNEL
--- 267,273 ----
* Then map first 1MB of ram in case it contains our boot params.
*/
add r0, r4, #PAGE_OFFSET >> 18
+ orr r6, r7, r5
str r6, [r0]
#ifdef CONFIG_XIP_KERNEL
On the Cirrus Logic ep93xx, system RAM isn't one nice physically
contiguous region as it is on most SoCs, but it is spread out over
between one and four memory banks.
What's worse, RAM doesn't necessarily start at any fixed physical
memory location. The start of RAM (PHYS_OFFSET) is not only board-
specific, but on some boards also depends on jumper settings (whether
async or sync boot mode is selected.)
The attached patch adds the RUNTIME_PHYS_OFFSET config option, which,
if selected, turns PHYS_OFFSET into a variable which is determined and
set by __create_page_tables by looking at the current pc. This allows
booting a single kernel image on all the different flavors of ep93xx
boards, reducing user confusion and hopefully pleasing our kautobuild
admin :-) If the option isn't selected, there's zero impact.
Signed-off-by: Lennert Buytenhek <buytenh@xxxxxxxxxxxxxx>
===================================================================
20070202 modified to apply cleanly to linux-2.6.20-rc7 - NZG
===================================================================
diff -Naur linux-2.6.20-rc7/arch/arm/Kconfig
linux-2.6.20-rc7-e1.0/arch/arm/Kconfig
--- linux-2.6.20-rc7/arch/arm/Kconfig 2007-02-02 10:26:21.000000000 -0600
+++ linux-2.6.20-rc7-e1.0/arch/arm/Kconfig 2007-02-02 16:23:05.000000000
-0600
@@ -113,6 +113,9 @@
help
The base address of exception vectors.
+config RUNTIME_PHYS_OFFSET
+ bool
+
source "init/Kconfig"
menu "System Type"
@@ -187,6 +190,7 @@
bool "EP93xx-based"
select ARM_AMBA
select ARM_VIC
+ select RUNTIME_PHYS_OFFSET
help
This enables support for the Cirrus EP93xx series of CPUs.
diff -Naur linux-2.6.20-rc7/arch/arm/boot/compressed/Makefile
linux-2.6.20-rc7-e1.0/arch/arm/boot/compressed/Makefile
--- linux-2.6.20-rc7/arch/arm/boot/compressed/Makefile 2006-11-29
15:57:37.000000000 -0600
+++ linux-2.6.20-rc7-e1.0/arch/arm/boot/compressed/Makefile 2007-02-02
16:23:05.000000000 -0600
@@ -78,13 +78,10 @@
EXTRA_CFLAGS := -fpic
EXTRA_AFLAGS :=
-# Supply ZRELADDR, INITRD_PHYS and PARAMS_PHYS to the decompressor via
-# linker symbols. We only define initrd_phys and params_phys if the
-# machine class defined the corresponding makefile variable.
+# Supply ZRELADDR and PARAMS_PHYS to the decompressor via linker
+# symbols. We only define params_phys if the machine class defined
+# the corresponding makefile variable.
LDFLAGS_vmlinux := --defsym zreladdr=$(ZRELADDR)
-ifneq ($(INITRD_PHYS),)
-LDFLAGS_vmlinux += --defsym initrd_phys=$(INITRD_PHYS)
-endif
ifneq ($(PARAMS_PHYS),)
LDFLAGS_vmlinux += --defsym params_phys=$(PARAMS_PHYS)
endif
diff -Naur linux-2.6.20-rc7/arch/arm/boot/compressed/head.S
linux-2.6.20-rc7-e1.0/arch/arm/boot/compressed/head.S
--- linux-2.6.20-rc7/arch/arm/boot/compressed/head.S 2006-11-29
15:57:37.000000000 -0600
+++ linux-2.6.20-rc7-e1.0/arch/arm/boot/compressed/head.S 2007-02-02
16:23:05.000000000 -0600
@@ -156,6 +156,11 @@
.text
adr r0, LC0
ldmia r0, {r1, r2, r3, r4, r5, r6, ip, sp}
+#ifdef CONFIG_RUNTIME_PHYS_OFFSET
+ and r10, pc, #0xf0000000 @ fix up zreladdr
+ add r4, r4, r10
+#endif
+
subs r0, r0, r1 @ calculate the delta offset
@ if delta is zero, we are
diff -Naur linux-2.6.20-rc7/arch/arm/kernel/head.S
linux-2.6.20-rc7-e1.0/arch/arm/kernel/head.S
--- linux-2.6.20-rc7/arch/arm/kernel/head.S 2007-02-02 10:26:21.000000000
-0600
+++ linux-2.6.20-rc7-e1.0/arch/arm/kernel/head.S 2007-02-02
16:36:21.000000000 -0600
@@ -43,8 +43,8 @@
.globl swapper_pg_dir
.equ swapper_pg_dir, KERNEL_RAM_VADDR - 0x4000
- .macro pgtbl, rd
- ldr \rd, =(KERNEL_RAM_PADDR - 0x4000)
+ .macro pgtbl, rd, phys_offset
+ add \rd, \phys_offset, #(TEXT_OFFSET - 0x4000)
.endm
#ifdef CONFIG_XIP_KERNEL
@@ -206,10 +206,22 @@
* Returns:
* r0, r3, r6, r7 corrupted
* r4 = physical page table address
+ * r5 = PHYS_OFFSET
*/
.type __create_page_tables, %function
__create_page_tables:
- pgtbl r4 @ page table address
+#ifdef CONFIG_RUNTIME_PHYS_OFFSET
+ adr r5, stext
+ sub r5, r5, #TEXT_OFFSET @ r5 = phys_offset
+
+ ldr r4, =(phys_offset - PAGE_OFFSET)
+ add r4, r4, r5
+ str r5, [r4] @ save phys_offset
+#else
+ mov r5, #PHYS_OFFSET @ r5 = phys_offset
+#endif
+
+ pgtbl r4, r5 @ r4 = page table address
/*
* Clear the 16K level 1 swapper page table
@@ -255,8 +267,7 @@
* Then map first 1MB of ram in case it contains our boot params.
*/
add r0, r4, #PAGE_OFFSET >> 18
- orr r6, r7, #(PHYS_OFFSET & 0xff000000)
- orr r6, r6, #(PHYS_OFFSET & 0x00e00000)
+ orr r6, r7, r5
str r6, [r0]
#ifdef CONFIG_XIP_KERNEL
diff -Naur linux-2.6.20-rc7/arch/arm/kernel/setup.c
linux-2.6.20-rc7-e1.0/arch/arm/kernel/setup.c
--- linux-2.6.20-rc7/arch/arm/kernel/setup.c 2007-02-02 10:26:21.000000000
-0600
+++ linux-2.6.20-rc7-e1.0/arch/arm/kernel/setup.c 2007-02-02
16:23:05.000000000 -0600
@@ -59,6 +59,16 @@
extern int root_mountflags;
extern void _stext, _text, _etext, __data_start, _edata, _end;
+#ifdef CONFIG_RUNTIME_PHYS_OFFSET
+/*
+ * The assignment is here solely to prevent this variable from ending
+ * up in bss. As the early startup code writes to it, we don't want it
+ * to be zeroed again later.
+ */
+unsigned long phys_offset = 0xdeadbeef;
+EXPORT_SYMBOL(phys_offset);
+#endif
+
unsigned int processor_id;
unsigned int __machine_arch_type;
EXPORT_SYMBOL(__machine_arch_type);
@@ -749,7 +759,7 @@
{ tag_size(tag_core), ATAG_CORE },
{ 1, PAGE_SIZE, 0xff },
{ tag_size(tag_mem32), ATAG_MEM },
- { MEM_SIZE, PHYS_OFFSET },
+ { MEM_SIZE, 0 },
{ 0, ATAG_NONE }
};
@@ -770,6 +780,8 @@
struct machine_desc *mdesc;
char *from = default_command_line;
+ init_tags.mem.start = PHYS_OFFSET;
+
setup_processor();
mdesc = setup_machine(machine_arch_type);
machine_name = mdesc->name;
diff -Naur linux-2.6.20-rc7/arch/arm/mach-ep93xx/Makefile.boot
linux-2.6.20-rc7-e1.0/arch/arm/mach-ep93xx/Makefile.boot
--- linux-2.6.20-rc7/arch/arm/mach-ep93xx/Makefile.boot 2006-11-29
15:57:37.000000000 -0600
+++ linux-2.6.20-rc7-e1.0/arch/arm/mach-ep93xx/Makefile.boot 2007-02-02
16:23:05.000000000 -0600
@@ -1,2 +1 @@
zreladdr-y := 0x00008000
-params_phys-y := 0x00000100
diff -Naur linux-2.6.20-rc7/include/asm-arm/arch-ep93xx/memory.h
linux-2.6.20-rc7-e1.0/include/asm-arm/arch-ep93xx/memory.h
--- linux-2.6.20-rc7/include/asm-arm/arch-ep93xx/memory.h 2006-11-29
15:57:37.000000000 -0600
+++ linux-2.6.20-rc7-e1.0/include/asm-arm/arch-ep93xx/memory.h 2007-02-02
16:23:05.000000000 -0600
@@ -5,7 +5,9 @@
#ifndef __ASM_ARCH_MEMORY_H
#define __ASM_ARCH_MEMORY_H
+#ifndef CONFIG_RUNTIME_PHYS_OFFSET
#define PHYS_OFFSET UL(0x00000000)
+#endif
#define __bus_to_virt(x) __phys_to_virt(x)
#define __virt_to_bus(x) __virt_to_phys(x)
diff -Naur linux-2.6.20-rc7/include/asm-arm/memory.h
linux-2.6.20-rc7-e1.0/include/asm-arm/memory.h
--- linux-2.6.20-rc7/include/asm-arm/memory.h 2007-02-02 10:26:27.000000000
-0600
+++ linux-2.6.20-rc7-e1.0/include/asm-arm/memory.h 2007-02-02
16:23:05.000000000 -0600
@@ -73,6 +73,14 @@
*/
#define IOREMAP_MAX_ORDER 24
+/*
+ * PHYS_OFFSET determined at run time?
+ */
+#if defined(CONFIG_RUNTIME_PHYS_OFFSET) && !defined(__ASSEMBLY__)
+extern unsigned long phys_offset;
+#define PHYS_OFFSET (phys_offset)
+#endif
+
#else /* CONFIG_MMU */
/*
- Follow-Ups:
- References:
- [linux-cirrus] Problems with edb9302a on kernel-2.6.20-rc7
- From: NZG
- [linux-cirrus] Re: Problems with edb9302a on kernel-2.6.20-rc7
- From: Lennert Buytenhek
Other related posts:
- » [linux-cirrus] Problems with edb9302a on kernel-2.6.20-rc7
- » [linux-cirrus] Re: Problems with edb9302a on kernel-2.6.20-rc7
- » [linux-cirrus] Re: Problems with edb9302a on kernel-2.6.20-rc7
- » [linux-cirrus] Re: Problems with edb9302a on kernel-2.6.20-rc7
- [linux-cirrus] Problems with edb9302a on kernel-2.6.20-rc7
- From: NZG
- [linux-cirrus] Re: Problems with edb9302a on kernel-2.6.20-rc7
- From: Lennert Buytenhek