[eduos] correction of file eef.lds

when compiling eduos on linux you will probably get an error something like
ld: cannot open /work/Projects/EduOS/ecc/eef-stub.o:
here is the correction of eef.lds change this with your old one and it 
will compile without any probleme's

/* EduOS Executable Format
   LD Linker Script
*/

/*
 *  EduOS
 *  Copyright (C) 2001 Frank Cornelis <Frank.Cornelis@xxxxxxxxx>
 *
 *  This program is free software; you can redistribute it and/or modify
 *  it under the terms of the GNU General Public License as published by
 *  the Free Software Foundation; either version 2 of the License, or
 *  (at your option) any later version.
 *
 *  This program is distributed in the hope that it will be useful,
 *  but WITHOUT ANY WARRANTY; without even the implied warranty of
 *  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 *  GNU General Public License for more details.
 *
 *  You should have received a copy of the GNU General Public License
 *  along with this program; if not, write to the Free Software
 *  Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
 */

eef_version = 1;
eef_release = 0;
page_size = 4096;
stack_size = page_size;
data_alignment = page_size;
bss_alignment = 0x10;

ENTRY(main);

SECTIONS {
    .header : {
        BYTE(0x45);
        BYTE(0x45);
        BYTE(0x46);
        BYTE(eef_version);
        BYTE(eef_release);
        LONG(SIZEOF(.header));
        LONG(SIZEOF(.text));
        LONG(main);
        LONG(SIZEOF(.data));
        LONG(__data_start);
        LONG(SIZEOF(.bss));
        LONG(__bss_start);
        LONG(stack_size);
        LONG(__exit_addr);
    }
   
    . = 0x0;
    __text_start = .;
    .text : AT(LOADADDR(.header) + SIZEOF(.header)) {
        /* main = DEFINED(main) ? main : .; */       
        *(EXCLUDE_FILE(../ecc/eef-stub.o) .text)
        __exit_addr = .;
        ../ecc/eef-stub.o(.text)   
        FILL(0x90);
    }
    __text_end = .;
    . = ALIGN(data_alignment);
    __data_start = .;
    .data : AT(LOADADDR(.text) + SIZEOF(.text)) {
        *(.rodata)
        *(.data)
    }
    __data_end = .;
    . = ALIGN(bss_alignment);
    __bss_start = .;
    .bss : {
        *(.bss)
        *(COMMON)
    }
    __bss_end = .;
}

----------------------------------------
The EduOS home page can be found at:
http://studwww.rug.ac.be/~fcorneli/eduos
----------------------------------------

Other related posts: