FreeLists / si-list / [SI-LIST] Re: Crystal oscillator simulation in time domain byPspice

[Raymond Anderson <Raymond.Anderson@xxxxxxx>]

Although not exactly the oscillator topology that is being discussed, 
here is a spice deck for a Pierce crystal oscillator that runs under 
Hspice. In this simulation inital conditions were set to allow transient 
simulation (in particular a little current through the crystal's 
inductance, voltages set on C! and C2 and the use of the UIC keyword in 
the .tran line).

This example circuit came from the book "Spice for Microelectronic 
Circuits" 1st editon by Roberts and Sedra (see 
http://www.macs.ece.mcgill.ca/~roberts/ROBERTS/SPICE/SPICE_Decks/spicedecks_ed1_index.html
 
) (Figure 12.9)

The output level is pretty low (about 23mV p-p) but it does indeed 
simulate and illustrates some techniques that may be useful in general 
for oscillator simulations.

(Simulation took about 154 seconds on a Sun-Fire-880 server running 
1200MHz UltraSparc III+ processors)

-Ray Anderson
Sun Microsystems Inc.
----------------------------------------------------------------

A Pierce Crystal Oscillator

** Circuit Description **

* 3.579545Mhz color burst, AT cut, parallel resonant, Q=25000,
.subckt colorburst_crystal 1 2
 l 1 11 0.0555779237 IC=1uA
 cs 11 12 3.56169600e-014
 r 12 2 50
 cp 1 2 8.90424001e-012
.ends

** Main Circuit **
* power supplies
Vdd 1 0 DC +5V
* oscillator circuit
Mp 2 3 1 1 pmos_transistor L=5u W=200u
Mn 2 3 0 0 nmos_transistor L=5u W=100u
Rf 2 3 10Meg
R1 2 4 75k
Xtal 3 4 colorburst_crystal
C1 3 0 10pF IC=2.5V
C2 4 0 10pF IC=2.5V
* model statement
.model pmos_transistor PMOS (kp=10u Vto=-1V lambda=0.04)
.model nmos_transistor NMOS (kp=20u Vto=+1V lambda=0.04)
** Analysis Requests **
.options limpts=100000 itl5=0 opts numdgt=7
.width out=80
* use the DC bias point as the initial conditions for the oscillator
.TRAN 20ns 20ms 0.0199972 20ns UIC
*.tran 20ns 20ms UIC
.FOUR 3.579MegHz
** Output Requests **
*.PRINT TRAN V(2)
.option post probe
.probe v(2)
.end
-----------------------------------------------------
~




------------------------------------------------------------------
To unsubscribe from si-list:
si-list-request@xxxxxxxxxxxxx with 'unsubscribe' in the Subject field

or to administer your membership from a web page, go to:
http://www.freelists.org/webpage/si-list

For help:
si-list-request@xxxxxxxxxxxxx with 'help' in the Subject field

List FAQ wiki page is located at:
                http://si-list.org/wiki/wiki.pl?Si-List_FAQ

List technical documents are available at:
                http://www.si-list.org

List archives are viewable at:     
                http://www.freelists.org/archives/si-list
or at our remote archives:
                http://groups.yahoo.com/group/si-list/messages
Old (prior to June 6, 2001) list archives are viewable at:
                http://www.qsl.net/wb6tpu